Max30102 Sensörü Nedir ve Nasıl Kullanılır?
Max30102 sensörü, içerisinde nabız sensörü ve pulse oksimetre içeren bir modüldür.Dahili LED’ler, fotodedektörler, optik elemanlar ve ortam ışığını reddeden düşük gürültülü elektronikler içerir.MAX30102, mobil ve giyilebilir cihazlar için tasarım sürecini kolaylaştırmak için eksiksiz bir sistem çözümü sunar.
Max30102 sensörü, 3.3V güç kaynağı ile çalışır. İletişim, standart bir I2C uyumlu arayüz aracılığıyla gerçekleştirilir. Modül, sıfır bekleme akımıyla yazılım aracılığıyla kapatılabilir, bu da güç raylarının her zaman güçte kalmasına izin verir.
Max30102 Sensörü Teknik Özellikleri
- Nabız monitörü ve nabız oksimetre sensörü bir arada bulunmaktadır.
- Minik 5,6 mm x 3,3 mm x 1,55 mm 14-Pin optik modül
- Modülün verimli çalışması için entegre kapak camı içermektedir.
- Mobil cihazlar için ultra düşük güçte çalışmaktadır.
- Programlanabilir örnekleme hızı ve led akımı güç tasarrufu.
- Düşük çüçte nabız monitörü (< 1mW)
- Ultra düşük kapatma akımı (0.7µA, tip)
- Hızlı veri çıkış yeteneği.
- Yüksek örnekleme oranı
- Sağlam hareket yapısı esnekliği
- Yüksek SNR
- -40°C ila +85°C çalışma sıcaklığı aralığı.
Max30102 Sensörü Pin Diyagramı
Bu sensörün 8 pini vardır ama biz 4 pinini kullanmaktayız.
- VCC(VIN): Modül güç kaynağı, 3 ile 5 V ararasında beslenebilir.
- GND: Toprak
- SCL: I2C clock pini
- SDA: I2C data pini
Piyasada iki farklı şekilde bulabilirsiniz. Bunların farklı olması sizi şaşırtmasın aynı kodlama ve doğru pin bağlantısı ile iki modülüde çalıştırabilirsiniz.
Max30102 Sensörü Kullanımı
- Devre Bağlantısı: Aşağıdaki devre Arduino’yu MAX30102 modülüne nasıl bağlamanız gerektiğini göstermektedir. Kabloları buna göre bağlayın.
- Kütüphane Yüklemesi: Kitaplık yöneticisine gidin ve Max30’u arayın, ardından SparkFun Max301x’i yükleyin.
Max30102 Sensörü İle Nabız İzleme
Aşağıdaki kodu Arduino’nuza yükleyin. Bu kod, kalp atış hızınızı seri monitörde grafik olarak görüntüler.
/*
MAX30102- Heart Rate Pulse Detection-Module
Home
Based on Arduino Library Example
*/
#include <Wire.h>
#include "MAX30105.h"
MAX30105 particleSensor;
void setup()
{
Serial.begin(115200);
Serial.println("Initializing...");
// Initialize sensor
if (!particleSensor.begin(Wire, I2C_SPEED_FAST)) //Use default I2C port, 400kHz speed
{
Serial.println("MAX30105 was not found. Please check wiring/power. ");
while (1);
}
//Setup to sense a nice looking saw tooth on the plotter
byte ledBrightness = 0x1F; //Options: 0=Off to 255=50mA
byte sampleAverage = 8; //Options: 1, 2, 4, 8, 16, 32
byte ledMode = 3; //Options: 1 = Red only, 2 = Red + IR, 3 = Red + IR + Green
int sampleRate = 100; //Options: 50, 100, 200, 400, 800, 1000, 1600, 3200
int pulseWidth = 411; //Options: 69, 118, 215, 411
int adcRange = 4096; //Options: 2048, 4096, 8192, 16384
particleSensor.setup(ledBrightness, sampleAverage, ledMode, sampleRate, pulseWidth, adcRange); //Configure sensor with these settings
//Arduino plotter auto-scales annoyingly. To get around this, pre-populate
//the plotter with 500 of an average reading from the sensor
//Take an average of IR readings at power up
const byte avgAmount = 64;
long baseValue = 0;
for (byte x = 0 ; x < avgAmount ; x++)
{
baseValue += particleSensor.getIR(); //Read the IR value
}
baseValue /= avgAmount;
//Pre-populate the plotter so that the Y scale is close to IR values
for (int x = 0 ; x < 500 ; x++)
Serial.println(baseValue);
}
void loop()
{
Serial.println(particleSensor.getIR()); //Send raw data to plotter
}Ardından, veri aktarım hızı 115.200’dür. Bu numarayı Seri çizicide de ayarlamalısınız. Örnekleme 400 kHz frekansında yapılmaktadır. Son olarak, sonuçlar Seri Çizicide aşağıdaki gibi görünür. Gördüğünüz gibi kalp atış hızı dalgalanıyor:.
Max30102 Sensörü İle Oksijen(SP02) Ölçme
Aşağıdaki kodu Arduino’nuza yükleyin. Bu kod, seri monitörde kan oksijeninizi göstermektedir.
/*
MAX30102- Blood Oxyge -Module
Home
Based on Arduino Library Example
*/
#include <Wire.h>
#include "MAX30105.h"
#include "spo2_algorithm.h"
MAX30105 particleSensor;
#define MAX_BRIGHTNESS 255
#if defined(__AVR_ATmega328P__) || defined(__AVR_ATmega168__)
//Arduino Uno doesn't have enough SRAM to store 100 samples of IR led data and red led data in 32-bit format
//To solve this problem, 16-bit MSB of the sampled data will be truncated. Samples become 16-bit data.
uint16_t irBuffer[100]; //infrared LED sensor data
uint16_t redBuffer[100]; //red LED sensor data
#else
uint32_t irBuffer[100]; //infrared LED sensor data
uint32_t redBuffer[100]; //red LED sensor data
#endif
int32_t bufferLength; //data length
int32_t spo2; //SPO2 value
int8_t validSPO2; //indicator to show if the SPO2 calculation is valid
int32_t heartRate; //heart rate value
int8_t validHeartRate; //indicator to show if the heart rate calculation is valid
byte pulseLED = 11; //Must be on PWM pin
byte readLED = 13; //Blinks with each data read
void setup()
{
Serial.begin(115200); // initialize serial communication at 115200 bits per second:
pinMode(pulseLED, OUTPUT);
pinMode(readLED, OUTPUT);
// Initialize sensor
if (!particleSensor.begin(Wire, I2C_SPEED_FAST)) //Use default I2C port, 400kHz speed
{
Serial.println(F("MAX30105 was not found. Please check wiring/power."));
while (1);
}
Serial.println(F("Attach sensor to finger with rubber band. Press any key to start conversion"));
while (Serial.available() == 0) ; //wait until user presses a key
Serial.read();
byte ledBrightness = 60; //Options: 0=Off to 255=50mA
byte sampleAverage = 4; //Options: 1, 2, 4, 8, 16, 32
byte ledMode = 2; //Options: 1 = Red only, 2 = Red + IR, 3 = Red + IR + Green
byte sampleRate = 100; //Options: 50, 100, 200, 400, 800, 1000, 1600, 3200
int pulseWidth = 411; //Options: 69, 118, 215, 411
int adcRange = 4096; //Options: 2048, 4096, 8192, 16384
particleSensor.setup(ledBrightness, sampleAverage, ledMode, sampleRate, pulseWidth, adcRange); //Configure sensor with these settings
}
void loop()
{
bufferLength = 100; //buffer length of 100 stores 4 seconds of samples running at 25sps
//read the first 100 samples, and determine the signal range
for (byte i = 0 ; i < bufferLength ; i++)
{
while (particleSensor.available() == false) //do we have new data?
particleSensor.check(); //Check the sensor for new data
redBuffer[i] = particleSensor.getRed();
irBuffer[i] = particleSensor.getIR();
particleSensor.nextSample(); //We're finished with this sample so move to next sample
Serial.print(F("red="));
Serial.print(redBuffer[i], DEC);
Serial.print(F(", ir="));
Serial.println(irBuffer[i], DEC);
}
//calculate heart rate and SpO2 after first 100 samples (first 4 seconds of samples)
maxim_heart_rate_and_oxygen_saturation(irBuffer, bufferLength, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);
//Continuously taking samples from MAX30102. Heart rate and SpO2 are calculated every 1 second
while (1)
{
//dumping the first 25 sets of samples in the memory and shift the last 75 sets of samples to the top
for (byte i = 25; i < 100; i++)
{
redBuffer[i - 25] = redBuffer[i];
irBuffer[i - 25] = irBuffer[i];
}
//take 25 sets of samples before calculating the heart rate.
for (byte i = 75; i < 100; i++)
{
while (particleSensor.available() == false) //do we have new data?
particleSensor.check(); //Check the sensor for new data
digitalWrite(readLED, !digitalRead(readLED)); //Blink onboard LED with every data read
redBuffer[i] = particleSensor.getRed();
irBuffer[i] = particleSensor.getIR();
particleSensor.nextSample(); //We're finished with this sample so move to next sample
//send samples and calculation result to terminal program through UART
Serial.print(F("red="));
Serial.print(redBuffer[i], DEC);
Serial.print(F(", ir="));
Serial.print(irBuffer[i], DEC);
Serial.print(F(", HR="));
Serial.print(heartRate, DEC);
Serial.print(F(", HRvalid="));
Serial.print(validHeartRate, DEC);
Serial.print(F(", SPO2="));
Serial.print(spo2, DEC);
Serial.print(F(", SPO2Valid="));
Serial.println(validSPO2, DEC);
}
//After gathering 25 new samples recalculate HR and SP02
maxim_heart_rate_and_oxygen_saturation(irBuffer, bufferLength, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);
}
}Bu kodda kitaplığın eklenmesi, hız ve veri aktarım hızının ayarlanması yapılır. İstenilen bir düğmeye basıldıktan sonra kan oksijen hesaplamasının başladığına dikkat edin. Sonuçlar aşağıdaki gibidir. Gördüğünüz gibi kandaki oksijen 96 ölçüldü.
